Snabbstart

Den här guiden tar dig från ingenting till ett Status200-projekt som hanteras av Terraform på ungefär tio minuter. Du skapar en API-nyckel, riktar Terraform mot ditt projekt och tillämpar en etikett, en monitor som kontrollerar din webbplats och en privat statussida som visar den. Sedan ändrar du en av dem och städar upp.

Innan du börjar#

• Terraform 1.5 eller senare, eller OpenTofu 1.6 eller senare. Med OpenTofu kör du tofu överallt där den här guiden kör terraform.
• Ett Status200-projekt på status200.ru eller på ditt eget Status200, där du kan skapa API-nycklar.
• På Status200 Cloud abonnemanget Growth eller högre. Ett projekts API-nycklar fungerar bara på det.

Skapa dina första resurser#

1. Skapa en API-nyckel till projektet#

   Öppna Projektinställningar → Avancerad → API-nycklar i Status200s instrumentpanel och klicka på Skapa API-nyckel. Ge den ett Namn, till exempel terraform, och välj Projektadministratör under Åtkomst: Terraform skapar, läser, ändrar och tar bort alla slags poster som det hanterar, och Projektadministratör får göra allt det. För en mer begränsad nyckel väljer du Välj behörigheter senare och lägger bara till de behörigheter som du behöver på nyckelns sida.

   Nyckeln går ut om ett år. För att välja ett annat datum öppnar du Fler fält innan du skapar den, eller ändrar datumet senare på nyckelns sida. När nyckeln har skapats öppnas dess sida: kopiera API-nyckel från kortet Detaljer om API-nyckel.

2. Gör nyckeln tillgänglig för Terraform#

   Lägg nyckeln i miljövariabeln STATUS200_API_KEY i det skal där du kör Terraform, så att den aldrig hamnar i en fil:

   LinuxmacOSWindows

   Linux

   Bash

   export STATUS200_API_KEY="<your-api-key>"

   macOS

   Bash

   export STATUS200_API_KEY="<your-api-key>"

   Windows

   PowerShell

   $env:STATUS200_API_KEY = "<your-api-key>"

3. Rikta Terraform mot Status200#

   Skapa en tom mapp, och i den en fil med namnet main.tf:

   main.tfHCL

   terraform {
     required_providers {
       oneuptime = {
         source  = "oneuptime/status200"
         version = "~> 14.0"
       }
     }
   }
   
   provider "oneuptime" {
     # The API key comes from STATUS200_API_KEY.
     # On a self-hosted Status200, add your Status200's address:
     # status200_url = "https://status200.example.com"
   }

   På ett självhostat Status200 läser du Självhostad konfiguration innan du väljer en providerversion.

4. Beskriv dina resurser#

   Lägg till de här blocken i main.tf. De läser två av de monitorstatusar som varje projekt börjar med, och skapar en etikett, en monitor som kontrollerar https://example.com var femte minut (ange din egen webbplats där) och en privat statussida som visar monitorn:

   main.tfHCL

   data "status200_monitor_status" "operational" {
     name = "Operational"
   }
   
   data "status200_monitor_status" "offline" {
     name = "Offline"
   }
   
   resource "status200_label" "critical" {
     name        = "critical"
     description = "Resources that page on-call when down"
     color       = "#FF5733"
   }
   
   resource "status200_monitor" "homepage" {
     name                = "Homepage"
     description         = "Checks that the homepage responds"
     monitor_type        = "Website"
     monitoring_interval = "*/5 * * * *"
     labels              = [status200_label.critical.id]
   
     monitor_steps = [{
       monitor_destination      = "https://example.com"
       monitor_destination_type = "URL"
       request_type             = "GET"
   
       criteria = [
         {
           name                  = "Offline"
           description           = "The homepage does not respond"
           filter_condition      = "Any"
           change_monitor_status = true
           monitor_status_id     = data.status200_monitor_status.offline.id
   
           filters = [
             {
               check_on    = "Is Online"
               filter_type = "False"
             }
           ]
         },
         {
           name                  = "Online"
           description           = "The homepage responds"
           filter_condition      = "All"
           change_monitor_status = true
           monitor_status_id     = data.status200_monitor_status.operational.id
   
           filters = [
             {
               check_on    = "Is Online"
               filter_type = "True"
             }
           ]
         }
       ]
     }]
   }
   
   resource "status200_status_page" "internal" {
     name                  = "Internal Status"
     description           = "Status of our internal services"
     page_title            = "Service Status"
     is_public_status_page = false
   }
   
   resource "status200_status_page_resource" "homepage" {
     status_page_id = status200_status_page.internal.id
     monitor_id     = status200_monitor.homepage.id
     display_name   = "Homepage"
   }
   
   output "monitor_id" {
     value = status200_monitor.homepage.id
   }

   Monitorns monitor_steps säger vad den kontrollerar och vad varje resultat betyder: efter varje kontroll sätter det första kriterium som stämmer dess status. Monitorsteg förklarar varje del.

5. Planera och tillämpa#

   TerraformOpenTofu

   Terraform

   Bash

   terraform init
   terraform plan
   terraform apply

   OpenTofu

   Bash

   tofu init
   tofu plan
   tofu apply

   init hämtar providern. Planen slutar med Plan: 4 to add, 0 to change, 0 to destroy. Skriv yes för att tillämpa den; när den är klar skriver Terraform ut den nya monitorns ID.

6. Kontrollera instrumentpanelen#

   I Status200s instrumentpanel:

   • Monitorer visar Homepage, med etiketten critical. Dess första kontroll kommer in inom några minuter.
   • Statussidor visar Internal Status, som visar Homepage.
   • Projektinställningar → Grundläggande → Etiketter visar critical, i den färg som du angav.

   Kör terraform plan igen. Den svarar No changes.: Status200 innehåller exakt det som konfigurationen säger.

Ändra en resurs#

Ändra konfigurationen, inte instrumentpanelen. Sätt etikettens color till "#2ECC71" i main.tf, och planera och tillämpa sedan:

terraform plan
terraform apply

Planen slutar med Plan: 0 to add, 1 to change, 0 to destroy.: etiketten ändras på plats. En ändring som någon gör i instrumentpanelen på en resurs som Terraform hanterar visas i nästa plan, och när du tillämpar den återställs det som konfigurationen säger.

Städa upp#

Om det här var en provtur tar du bort det som konfigurationen skapade:

terraform destroy

Det tar bort etiketten, monitorn, statussidan och dess resurs. De två monitorstatusarna blir kvar: datakällorna läser dem bara.

Felsökning#

Nästa steg#