Quick Start

This guide takes you from nothing to a Status200 project managed by Terraform in about ten minutes. You create an API key, point Terraform at your project, and apply a label, a monitor that checks your website, and a private status page that shows it. Then you change one of them and clean up.

Before you begin#

• Terraform 1.5 or later, or OpenTofu 1.6 or later. With OpenTofu, run tofu wherever this guide runs terraform.
• A Status200 project on status200.ru or on your own Status200, in which you can create API keys.
• On Status200 Cloud, the Growth plan or above. A project's API keys work only on it.

Create your first resources#

1. Create a project API key#

   In the Status200 dashboard, open Project Settings → Advanced → API Keys and click Create API Key. Give it a Name, such as terraform, and under Access pick Project Admin: Terraform creates, reads, changes and deletes every kind of record it manages, and Project Admin may do all of that. For a narrower key, pick Choose permissions later and add only the permissions you need on the key's page.

   The key expires a year from today. To pick another date, open More fields before you create it, or change the date on the key's page later. Once the key is created, its page opens: copy the API Key from the API Key Details card.

2. Make the key available to Terraform#

   Put the key in the STATUS200_API_KEY environment variable of the shell you run Terraform in, so it never lands in a file:

   LinuxmacOSWindows

   Linux

   Bash

   export STATUS200_API_KEY="<your-api-key>"

   macOS

   Bash

   export STATUS200_API_KEY="<your-api-key>"

   Windows

   PowerShell

   $env:STATUS200_API_KEY = "<your-api-key>"

3. Point Terraform at Status200#

   Make an empty folder, and in it a file named main.tf:

   main.tfHCL

   terraform {
     required_providers {
       oneuptime = {
         source  = "oneuptime/status200"
         version = "~> 14.0"
       }
     }
   }
   
   provider "oneuptime" {
     # The API key comes from STATUS200_API_KEY.
     # On a self-hosted Status200, add your Status200's address:
     # status200_url = "https://status200.example.com"
   }

   On a self-hosted Status200, read Self-Hosted Setup before you pick a provider version.

4. Describe your resources#

   Add these blocks to main.tf. They read two of the monitor statuses every project starts with, and create a label, a monitor that checks https://example.com every five minutes (put your own website there), and a private status page that shows the monitor:

   main.tfHCL

   data "status200_monitor_status" "operational" {
     name = "Работает"
   }
   
   data "status200_monitor_status" "offline" {
     name = "Не в сети"
   }
   
   resource "status200_label" "critical" {
     name        = "critical"
     description = "Resources that page on-call when down"
     color       = "#FF5733"
   }
   
   resource "status200_monitor" "homepage" {
     name                = "Homepage"
     description         = "Checks that the homepage responds"
     monitor_type        = "Website"
     monitoring_interval = "*/5 * * * *"
     labels              = [status200_label.critical.id]
   
     monitor_steps = [{
       monitor_destination      = "https://example.com"
       monitor_destination_type = "URL"
       request_type             = "GET"
   
       criteria = [
         {
           name                  = "Offline"
           description           = "The homepage does not respond"
           filter_condition      = "Any"
           change_monitor_status = true
           monitor_status_id     = data.status200_monitor_status.offline.id
   
           filters = [
             {
               check_on    = "Is Online"
               filter_type = "False"
             }
           ]
         },
         {
           name                  = "Online"
           description           = "The homepage responds"
           filter_condition      = "All"
           change_monitor_status = true
           monitor_status_id     = data.status200_monitor_status.operational.id
   
           filters = [
             {
               check_on    = "Is Online"
               filter_type = "True"
             }
           ]
         }
       ]
     }]
   }
   
   resource "status200_status_page" "internal" {
     name                  = "Internal Status"
     description           = "Status of our internal services"
     page_title            = "Service Status"
     is_public_status_page = false
   }
   
   resource "status200_status_page_resource" "homepage" {
     status_page_id = status200_status_page.internal.id
     monitor_id     = status200_monitor.homepage.id
     display_name   = "Homepage"
   }
   
   output "monitor_id" {
     value = status200_monitor.homepage.id
   }

   The monitor's monitor_steps say what it checks and what each result means: after each check, the first criteria that matches sets its status. Monitor Steps explains every part.

5. Plan and apply#

   TerraformOpenTofu

   Terraform

   Bash

   terraform init
   terraform plan
   terraform apply

   OpenTofu

   Bash

   tofu init
   tofu plan
   tofu apply

   init downloads the provider. The plan ends with Plan: 4 to add, 0 to change, 0 to destroy. Type yes to apply it; when it is done, Terraform prints the new monitor's ID.

6. Check the dashboard#

   In the Status200 dashboard:

   • Monitors lists Homepage, with the critical label. Its first check is in within a few minutes.
   • Status Pages lists Internal Status, which shows Homepage.
   • Project Settings → Basic → Labels lists critical, in the color you set.

   Run terraform plan again. It answers No changes.: Status200 holds exactly what the configuration says.

Change a resource#

Change the configuration, not the dashboard. Set the label's color to "#2ECC71" in main.tf, then plan and apply:

terraform plan
terraform apply

The plan ends with Plan: 0 to add, 1 to change, 0 to destroy.: the label is changed in place. A change someone makes in the dashboard to a resource Terraform manages shows in the next plan, and applying it puts back what the configuration says.

Clean up#

If this was a test drive, delete what the configuration created:

terraform destroy

It deletes the label, the monitor, the status page and its resource. The two monitor statuses stay: the data sources only read them.

Troubleshooting#

Next steps#